tor-browser

The Tor Browser
git clone https://git.dasho.dev/tor-browser.git
Log | Files | Refs | README | LICENSE

shim_headers.gni (1070B)

      1 # Copyright 2016 The Chromium Authors
      2 # Use of this source code is governed by a BSD-style license that can be
      3 # found in the LICENSE file.
      4 
      5 template("shim_headers") {
      6   action_name = "gen_${target_name}"
      7   config_name = "${target_name}_config"
      8   shim_headers_path = "${root_gen_dir}/shim_headers/${target_name}"
      9 
     10   config(config_name) {
     11     include_dirs = [ shim_headers_path ]
     12   }
     13 
     14   action(action_name) {
     15     script = "//tools/generate_shim_headers/generate_shim_headers.py"
     16     args = [
     17       "--generate",
     18       "--headers-root",
     19       rebase_path(invoker.root_path),
     20       "--output-directory",
     21       rebase_path(shim_headers_path),
     22     ]
     23     if (defined(invoker.prefix)) {
     24       args += [
     25         "--prefix",
     26         invoker.prefix,
     27       ]
     28     }
     29     args += invoker.headers
     30 
     31     outputs = []
     32     foreach(h, invoker.headers) {
     33       outputs += [ shim_headers_path + "/" +
     34                    rebase_path(invoker.root_path, "//") + "/" + h ]
     35     }
     36   }
     37 
     38   group(target_name) {
     39     deps = [ ":${action_name}" ]
     40     all_dependent_configs = [ ":${config_name}" ]
     41   }
     42 }