tor-browser

The Tor Browser
git clone https://git.dasho.dev/tor-browser.git
Log | Files | Refs | README | LICENSE

BUILD.gn (3172B)

      1 # Copyright 2021 The Chromium Authors
      2 # Use of this source code is governed by a BSD-style license that can be
      3 # found in the LICENSE file.
      4 
      5 import("//chromium/build/android/test/missing_symbol_test.gni")
      6 import("//chromium/build/config/android/android_nocompile.gni")
      7 import("//chromium/build/config/android/rules.gni")
      8 import("nocompile_sources.gni")
      9 
     10 template("lint_test") {
     11   _library_target_name = "${target_name}_test_java"
     12   _apk_target_name = "${target_name}_apk"
     13 
     14   android_library(_library_target_name) {
     15     sources = [ "//tools/android/errorprone_plugin/test/src/org/chromium/tools/errorprone/plugin/Empty.java" ]
     16     not_needed(invoker, [ "sources" ])
     17     if (enable_android_nocompile_tests) {
     18       sources += invoker.sources
     19     }
     20   }
     21 
     22   android_apk(_apk_target_name) {
     23     # This cannot be marked testonly since lint has special ignores for testonly
     24     # targets. We need to test linting a normal apk target.
     25     apk_name = _apk_target_name
     26     deps = [ ":$_library_target_name" ]
     27     android_manifest = "//chromium/build/android/AndroidManifest.xml"
     28   }
     29 
     30   android_lint(target_name) {
     31     _apk_target = ":${_apk_target_name}"
     32     deps = [ "${_apk_target}__java" ]
     33     build_config_dep = "$_apk_target$build_config_target_suffix"
     34     build_config = get_label_info(_apk_target, "target_gen_dir") + "/" +
     35                    get_label_info(_apk_target, "name") + ".build_config.json"
     36     if (enable_android_nocompile_tests) {
     37       skip_build_server = true
     38     }
     39   }
     40 }
     41 
     42 lint_test("default_locale_lint_test") {
     43   sources = default_locale_lint_test_nocompile_sources
     44 }
     45 
     46 lint_test("new_api_lint_test") {
     47   sources = new_api_lint_test_nocompile_sources
     48 }
     49 
     50 missing_symbol_generated_importer_test(
     51     "import_parent_missing_symbol_test_java") {
     52   importer_package = "test.missing_symbol.child_missing"
     53   imported_package = "test.missing_symbol"
     54   imported_class_name = "B"
     55   deps = [ ":b_java" ]
     56 }
     57 
     58 missing_symbol_test("import_child_missing_symbol_test_java") {
     59   sources = import_child_missing_symbol_test_nocompile_sources
     60   deps = [ ":sub_b_java" ]
     61 }
     62 
     63 missing_symbol_test("import_turbine_missing_symbol_test_java") {
     64   sources = import_turbine_missing_symbol_test_nocompile_sources
     65   deps = [ ":b_java" ]
     66 }
     67 
     68 missing_symbol_generated_importer_test("prebuilt_missing_symbol_test_java") {
     69   importer_package = "test.missing_symbol.prebuilt_missing"
     70   imported_package = "test.missing_symbol"
     71   imported_class_name = "C"
     72   deps = [ ":c_prebuilt_java" ]
     73 }
     74 
     75 missing_symbol_generated_importer_test(
     76     "cpp_template_missing_symbol_test_java") {
     77   importer_package = "test.missing_symbol.cpp_template_missing"
     78   imported_package = "test.missing_symbol"
     79   imported_class_name = "D"
     80   deps = [ ":d_java" ]
     81 }
     82 
     83 android_library("b_java") {
     84   sources = [ "../../java/test/missing_symbol/B.java" ]
     85 }
     86 
     87 android_library("sub_b_java") {
     88   sources = [ "../../java/test/missing_symbol/sub/SubB.java" ]
     89 }
     90 
     91 android_java_prebuilt("c_prebuilt_java") {
     92   jar_path = "../../java/test/missing_symbol/c.jar"
     93 }
     94 
     95 android_library("d_java") {
     96   srcjar_deps = [ ":d_template_javagen" ]
     97 }
     98 
     99 java_cpp_template("d_template_javagen") {
    100   sources = [ "../../java/test/missing_symbol/D.template" ]
    101 }